flake.nix - departures2mqtt

1 
2 
3 
4 
5 
6 
7 
8 
9 
10 
11 
12 
13 
14 
15 
16 
17 
18 
19 
20 
21 
22 
23 
24 
25 
26 
27 
28 
29 
30 
31 
32 
33 
34 
35 
36 
37 
38 
39 
40 
41 
42 
43 
44 
45 
46 
47 
48 
49 
50 
51 
52 
53 
54 
{

  description = "Send kvg-kiel bus departures to mqtt";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-22.11";

  outputs = inputs: let
    forAllSystems = function:
      inputs.nixpkgs.lib.genAttrs [
        "x86_64-linux"
        "aarch64-linux"
        "aarch64-darwin"
      ] (system: function (import inputs.nixpkgs {
        system   = system;
        overlays = [ inputs.self.overlays.default ];
      }));

  in {

    packages = forAllSystems (pkgs: {
      default         = pkgs.departures2mqtt;
      departures2mqtt = pkgs.departures2mqtt;
    });

    apps = forAllSystems (pkgs: {
      default.type    = "app";
      default.program = "${pkgs.departures2mqtt}/bin/departures2mqtt";
    });

    overlays.default = final: prev: {
      departures2mqtt = (
        let
          nmqtt = final.fetchFromGitHub {
            owner  = "zevv";
            repo   = "nmqtt";
            rev    = "v1.0.4";
            sha256 = "1by0xyqz754dny19lf8rpkg42passnj0rs6rk3jr763m1zr803mc";
          };

        in final.nimPackages.buildNimPackage {
          name = "departures2mqtt";
          src  = inputs.self;

          buildInputs = [ nmqtt ];

          nimBinOnly = true;
          nimRelease = true;
        }
      );
    };

  };

}